Import sources

2019-04-05 09:05:15 +02:00
parent e7048e66dd
commit f94c0f8540
9 changed files with 519 additions and 0 deletions
@@ -0,0 +1,96 @@
+buildscript {
+    repositories {
+        jcenter()
+        maven {
+            url "https://plugins.gradle.org/m2/"
+        }
+    }
+    dependencies {
+        classpath 'org.asciidoctor:asciidoctor-gradle-plugin:1.5.7'
+        //classpath 'org.asciidoctor:asciidoctorj-epub3:1.5.0-alpha.6'
+        classpath ('org.asciidoctor:asciidoctorj-pdf:1.5.0-alpha.16') {
+            exclude group: 'org.jruby'
+        }
+        classpath 'org.jruby:jruby:9.1.17.0'
+    }
+}
+
+apply plugin: 'org.asciidoctor.convert'
+apply plugin: 'java'
+apply plugin: 'maven'
+apply plugin: 'checkstyle'
+apply plugin: 'pmd'
+apply plugin: 'project-report'
+
+repositories {
+    mavenCentral()
+    jcenter()
+}
+
+sourceCompatibility = 1.8
+group = 'com.ibtp'
+version = '0.0.1-SNAPSHOT'
+description = 'Project Generations: Generative Programmierung in Java'
+
+final BUILD_DATE = new Date().format('dd.MM.yyyy').toString()
+
+asciidoctorj {
+    version = '1.6.0-alpha.7'
+}
+
+asciidoctor {
+    backends 'html5', 'pdf'
+    attributes 'build-gradle':       file('build.gradle'),
+               'source-highlighter': 'coderay',
+               'toc':                'left',
+               'toc-title':          'Inhaltsverzeichnis',
+               'revdate':            BUILD_DATE,
+               'revnumber':          version,
+               'idprefix':           'id_',
+               'chapter-label':      '',
+               'icons':              'font',
+               'setanchors':         '',
+               'idseparator':        '-',
+               'endpoint-url':       'http://www.ingenieurbuero-peetz.de',
+               'imagesdir':          './images',
+               'docinfo1':           ''
+}
+
+dependencies {
+    compile 'org.slf4j:slf4j-api:1.7.22'
+    testCompile 'junit:junit:4.12'
+    testCompile 'org.mockito:mockito-all:1.9.5'
+}
+
+checkstyle {
+    ignoreFailures = true
+    showViolations = false
+}
+
+pmd {
+    ignoreFailures = true
+    ruleSets = ["basic", "braces", "junit"]
+}
+
+jar {
+    manifest {
+        attributes 'Implementation-Title': 'Generations', 'Implementation-Version': version
+    }
+}
+
+uploadArchives {
+    repositories {
+        mavenDeployer {
+            repository(url: "https://nexus.ingenieurbuero-peetz.de/repository/ibtp-releases-internal/") {
+                authentication(userName: nexusUsername, password: nexusPassword)
+            }
+            snapshotRepository(url: "https://nexus.ingenieurbuero-peetz.de/repository/ibtp-snapshots-internal") {
+                authentication(userName: nexusUsername, password: nexusPassword)
+            }
+        }
+    }
+}
+
+wrapper {
+    gradleVersion = "5.2"
+}